73 lines
2.4 KiB
CMake
73 lines
2.4 KiB
CMake
# Set build-directive (used in core to tell which buildtype we used)
|
|
target_compile_definitions(trinity-compile-option-interface
|
|
INTERFACE
|
|
-D_BUILD_DIRECTIVE="$<CONFIG>")
|
|
|
|
set(CLANG_EXPECTED_VERSION 11.0.0)
|
|
|
|
if(CMAKE_CXX_COMPILER_VERSION VERSION_LESS CLANG_EXPECTED_VERSION)
|
|
message(FATAL_ERROR "Clang: TrinityCore requires version ${CLANG_EXPECTED_VERSION} to build but found ${CMAKE_CXX_COMPILER_VERSION}")
|
|
else()
|
|
message(STATUS "Clang: Minimum version required is ${CLANG_EXPECTED_VERSION}, found ${CMAKE_CXX_COMPILER_VERSION} - ok!")
|
|
endif()
|
|
|
|
if(WITH_WARNINGS)
|
|
target_compile_options(trinity-warning-interface
|
|
INTERFACE
|
|
-W
|
|
-Wall
|
|
-Wextra
|
|
-Wimplicit-fallthrough
|
|
-Winit-self
|
|
-Wfatal-errors
|
|
-Wno-mismatched-tags
|
|
-Woverloaded-virtual)
|
|
|
|
message(STATUS "Clang: All warnings enabled")
|
|
endif()
|
|
|
|
if(WITH_COREDEBUG)
|
|
target_compile_options(trinity-compile-option-interface
|
|
INTERFACE
|
|
-g3)
|
|
|
|
message(STATUS "Clang: Debug-flags set (-g3)")
|
|
endif()
|
|
|
|
# -Wno-narrowing needed to suppress a warning in g3d
|
|
# -Wno-deprecated-register is needed to suppress 185 gsoap warnings on Unix systems.
|
|
# -Wno-deprecated-copy needed to suppress a warning in g3d
|
|
set(CMAKE_CXX_FLAGS_DEBUG "${CMAKE_CXX_FLAGS_DEBUG} -DDEBUG=1")
|
|
target_compile_options(trinity-compile-option-interface
|
|
INTERFACE
|
|
-Wno-narrowing
|
|
-Wno-deprecated-register)
|
|
|
|
if(BUILD_SHARED_LIBS)
|
|
# -fPIC is needed to allow static linking in shared libs.
|
|
# -fvisibility=hidden sets the default visibility to hidden to prevent exporting of all symbols.
|
|
target_compile_options(trinity-compile-option-interface
|
|
INTERFACE
|
|
-fPIC)
|
|
|
|
target_compile_options(trinity-hidden-symbols-interface
|
|
INTERFACE
|
|
-fvisibility=hidden)
|
|
|
|
# --no-undefined to throw errors when there are undefined symbols
|
|
# (caused through missing TRINITY_*_API macros).
|
|
set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} --no-undefined")
|
|
|
|
message(STATUS "Clang: Disallow undefined symbols")
|
|
endif()
|
|
|
|
# speedup PCH builds by forcing template instantiations during PCH generation
|
|
set(CMAKE_REQUIRED_FLAGS "-fpch-instantiate-templates")
|
|
check_cxx_source_compiles("int main() { return 0; }" CLANG_HAS_PCH_INSTANTIATE_TEMPLATES)
|
|
unset(CMAKE_REQUIRED_FLAGS)
|
|
if(CLANG_HAS_PCH_INSTANTIATE_TEMPLATES)
|
|
target_compile_options(trinity-compile-option-interface
|
|
INTERFACE
|
|
-fpch-instantiate-templates)
|
|
endif()
|